En esta ocasión quería compartir contigo unos trucos increíbles que puedes aplicar a tus hojas de cálculo en Google Sheets con los que poder asombrar a aquellas personas que muestres que tu trabajo en la hoja de cálculo de Google es de nivel PRO.
Si estás leyendo esto, es porque te interesa mejorar tu destreza con la hoja de cálculo de Google y aquí te quiero comentar que la potencia que ofrece es muy amplia y que es posible realizar análisis o tratamiento de datos complejos. Es muy polivalente y tiene muchísimas utilidades que hace unos años no disponíamos y es que se va actualizando y mejorando con el tiempo.
Día a día aumenta el listado de fórmulas que incorpora Google Sheet y si lo que buscas no se encuentra entre ellas siempre podrás echar mano de Macros y del editor de secuencia de comandos para poder programar aquellas tareas más rutinarias o poder crear tú alguna función que necesites y no se encuentre en Google Sheets.
INICIO PRO EN GOOGLE SHEETS
Truco espectacular para comenzar a trabajar en Google Sheets y dejar a tus compañeros de oficina ojipláticos. Teclea en la barra de direcciones web del navegador el siguiente código «SHEET.NEW» para abrir una hoja de cálculo nueva:
Y en el caso de que trabajes con Microsoft Office 365 y desees crear una hoja de Excel online en blanco, prueba a teclear «EXCEL.NEW«, observa la magia de ver una nueva hoja de cálculo de excel en tu navegador:
Y si quieres ir más allá, guarda esta dirección como un icono en la barra de marcadores. Nada más pulsar el icono tendrás una nueva hoja de cálculo. Funciona tanto para Google Sheets como para Microsoft Excel Online.
ACCESO A LAS ÚLTIMAS HOJAS DE CÁLCULO ABIERTAS EN GOOGLE SHEETS
Y si lo que deseas es ver en qué hojas de cálculo has estado trabajando últimamente, puedes seleccionar la opción hojas de cálculo en Drive y ordenarlas por fecha más reciente. Con el siguiente código se obtienen las hojas de cálcuo de Drive:
https://drive.google.com/drive/search?q=type:spreadsheet
Puedes crear otro acceso directo en marcadores a esta dirección web y tendrás acceso a las últimas hojas de cálculo abiertas en Google Sheets a un solo clic de distancia.
En la barra de marcadores he añadido dos accesos directos:
- HC: Acceso a nueva Hoja de Cálculo
- Últimas HC: Últimas Hojas de Cálculo.
FUNCIONES PRO DE GOOGLE SHEETS
Tienes a tu disposición incontables fórmulas en Google Sheets, pero al final los importante no es conocerlas todas. Para eso está la ayuda, lo importante es conocer las fórmulas más útiles para tu día a día. Y en este caso, te muestro algunas que una vez las conozcas, serán una herramienta valiosa en tu catálogo de fórmulas y funciones PRO.
Intetaré mostrarte estos trucos Google Sheets avanzando según dificultad…
HIPERVÍNCULO
Comenzamos con esta fórmula que me ha sido muy útil en muchas ocasiones al presentar mis trabajos. Y es que si no quieres que se muestre toda la dirección web, utiliza esta fórmula para mostrar el texto deseado como link a la dirección web.
Uso: =HIPERVINCULO ( dirección web ; nombre del enlace )
Ejemplo:
=HIPERVINCULO ( "https://tecnoapuntes.com" ; "Web de Tecnoapuntes")
Finalmente lo que hago es mostrar solo el resultado de la columna A y el resto de columnas las oculto. Así todo el mundo con acceso a la hoja de cálculo tiene un enlace descriptivo que les envía a la dirección web enlazada.
IMAGEN CON LINK EN SHEETS
¿Y qué te parece una imagen con un hipervínculo que te lleva al enlace que le has proporcionado?
Con las fórmulas HIPERVINCULO e IMAGEN combinadas puedes lograr enlazar la imagen a una dirección web.
=HIPERVINCULO ( "https://tecnoapuntes.com" ; IMAGE("https://tecnoapuntes.com/wp-content/uploads/2017/08/logo-tecnoapuntes.com_.png")Te comparto mi hoja de cálculo para que puedas ver todos los trucos que he empleado en este tutorial. Haz click en la siguiente imagen para acceder:
CÓDIGOS QR EN HOJA DE CÁLCULO
En relación con lo anterior, Google Sheets es capaz de generar códigos QR a través de una función. Esto es muy útil cuando desees asociar un hipervínculo a un código QR.
La fórmula para crear un código QR es la siguiente:
=IMAGE("https://api.qrserver.com/v1/create-qr-code/?data="&ENCODEURL(E4))- Aquí E4 es la celda donde debe estar la dirección web de la que quieres generar el código QR
- Todo lo anterior es la llamada a la API de qrserver.com para generar el código QR. Qrserver genera el código QR y luego Google Sheets lo transforma a imagen con la función IMAGE.
- Utilizamos la función ENCODEURL para poder anexar el código a la dirección web de consulta y que lo trate como parte de un enlace.
- El tamaño del código por defecto es 200 x 200 píxeles, pero puedes probar a modificarlo para ajustar el tamaño a tu gusto. En el siguiente ejemplo he generado un código a 400 píxeles.
=IMAGE("https://api.qrserver.com/v1/create-qr-code/?size=400x400&data="&ENCODEURL(E4))
MÁS CÓDIGOS QR EN GOOGLE SHEETS
Aunque el más interesante puede ser el código QR asociado a un enlace web, tenemos otras opciones MUY INTERESANTES que les puedes sacar mucho provecho. En la siguiente imagen tienes las opciones para generar otros tipos de códigos que te ofrece la API de QR Code Generator.
Otros ejemplos de códigos QR que puedes generar automáticamente con Google Sheets…
COORDENADAS GEOGRÁFICAS CON CÓDIGOS QR
Si por ejemplo deseas proponer unos códigos QR con unas coordenadas, puedes generarlos con Google Sheets de forma muy sencilla. Solo es cuestión de incluir longitud y latitud y con la fórmula que te explico a continuación podrás generarlos automáticamente.
=IMAGE("https://api.qrserver.com/v1/create-qr-code/?data=geo:"&A12&","&B12)Donde A12 y A13 son las celdas con las coordenadas de longitud y latitud.
ENVIAR EMAILS CON CÓDIGOS QR Y SHEETS
¿Y que te parece que te envíen un email a través de un código QR? Interesante, no? Pues con esta opción puede enviar o recibir emails con la siguiente fórmula de Google Sheets:
=IMAGE("https://api.qrserver.com/v1/create-qr-code/?data=MATMSG:TO:"&ENCODEURL(A16)&";SUB:"&ENCODEURL(B16)&";BODY:"&ENCODEURL(C16))Esta fórmula es más compleja pero al final es unir cadenas de texto con la información para que la API de QRSERVER genere el código del e-mail.
COMPARTIR WIFI CON CÓDIGO QR Y SHEETS
¿Y que te parece tener un código QR para mostrar a quien quiera conocer tu WIFI? Pues con la siguiente función de Google Sheets puedes generar un código QR para mostrar:
=IMAGE("https://api.qrserver.com/v1/create-qr-code/?data=WIFI:T:WPA;S:"&ENCODEURL(A20)&";P:"&ENCODEURL(B20))
NÚMERO TELEFÓNICO CON CÓDIGO QR Y SHEETS
Y si quieres compartir un número de teléfono para que realice una llamada al escanear el código QR, puedes generarlo con Google Sheets de la siguiente función:
=IMAGE("https://api.qrserver.com/v1/create-qr-code/?data=tel:"&ENCODEURL(A24))
Te comparto la hoja de cálculo con trucos Google Sheets PRO para que puedas ver todos los trucos que he empleado en este tutorial. Haz clic en la siguiente imagen para acceder:
EL ÚLTIMO DE LA FILA
Este truco es muy útil cuando tienes una lista que va creciendo y creciendo porque se van añadiendo ítems y más ítems. Si quieres obtener siempre el valor de la última celda añadida, el último ítem.
Por ejemplo, resulta muy útil cuando tienes un formulario de Google asociado a una hoja de cálculo de Google. Sabes que se va completando automáticamente según lo van realizando, por lo que siempre podrás obtener quien ha sido el último en completar el formulario.
En este caso, si deseas conocer cuál es el último ítem en la columna A, la fórmula será:
=INDICE(A:A;CONTARA(A:A);1)Te explico el código:
- CONTARA(A:A) realiza la cuenta del número de ítems en la columna A.
- INDICE(A:A; Nºítems; 1) obtiene el ítem de la primera columna «1″ en la posición «Nº ítems» del rango «A:A» que es la columna A.
EMOTICONOS EN GOOGLE SHEETS
Junto con los gráficos e imágenes añadir emoticonos para darle a tu hoja de cálculo una expresividad antes no vista evitando que sean sosas y aburridas. Los emojis en Google Sheets pueden aportar un mayor impacto visual a tus hojas de cálculo. Como en la imagen siguiente de clasificación de películas.
Observa que para ello convertimos el código numérico Unicode a carácter con la función CARACTER. Observa la tabla siguiente con los códigos Unicode de los emojis. Te dejo un ejemplo de los códigos utilizados para crear la clasificación de films por estrellas que he creado.
Puedes encontrar más códigos unicode en la página alt-codes.net donde incluso te ofrece la posibilidad de copiar los iconos desde su web y poder pegarlos en tu hoja de cálculo de Google Sheets.
=REPETIR(INDICE($B$14:$B$23;$E$1;1);B2)&SI($G$1="SI";REPETIR(INDICE($B$14:$B$23;1;1);5-B2);"")Te explico la función:
- INDICE(rango ; fila ; columna) -> toma el valor dentro del rango indicado por fila y columna.
- REPETIR(texto o celda ; nºrepeticiones) -> repite el texto o la celda el número de repeticiones que le indiquemos.
Entre los trucos Google Sheets, insertar imágenes y utilizar emojis es de los que más recurro para darle vistosidad e impacto a mis hojas de cálculo.
SPARKLINE – GRÁFICOS EN CELDAS
Dentro de los trucos Google Sheets que debes conocer, SPARKLINE, es una herramienta muy útil para dar mayor expresividad a tu hoja de cálculo y que permite mostrar datos para que sean comprendidos con mayor facilidad visualmente.
Con la función SPARKLINE de Google Sheets puedes insertar minigráficos en una celda que pueden ser gráficos de barras, columnas, líneas, etc.
Puedes consultar información detallada en Sparkline_de_Google.com con detallados ejemplos de las posibilidades que ofrece.
Como puedes ver, con la función SPARKLINE tienes 4 posibilidades de mostrar un gráfico en una celda:
- Líneas
- Barras
- Columnas
- Win/Loss
Si deseas crear gráficas de líneas, tienes el siguiente código con opciones para cambiar el grosor de la línea y el color.
=SPARKLINE( RANGODATOS ;{"charttype"\"line";"linewidth"\2;"color"\"#5f88cc"})El gráfico de barras con SPARKLINE que he creado le he dado colores azul y rojo.
=SPARKLINE(C2:E2;{"charttype"\"bar";"color1"\"blue";"color2"\"red"})Si deseas un gráfico de columnas con tres colores, puedes utilizar el siguiente código.
=SPARKLINE(C2:E2 ;{"charttype"\"column";"lowcolor"\"red";"highcolor"\"green";"color"\"orange"})Y finalmente un gráfico SPARKLINE winloss con el azul para el positivo y el rojo para el negativo.
=SPARKLINE(G2:G11 ;{"charttype"\"winloss";"color"\"blue";"negcolor"\"red"})Y si deseas combinar SPARKLINE con GOOGLEFINANCE puedes obtener los gráficos de todas las acciones que desees solo con el ticker de la acción y el siguiente código. Donde en la celda A17 debes colocar el ticker de la acción.
=SPARKLINE( GOOGLEFINANCE(A17;"price";HOY()-365;HOY();"DAILY") ;{"charttype"\"line";"linewidth"\2;"color"\"#5f88cc"})Y estos son todos los trucos por hoy, no olvides que puedes encontrar más información de utilidad sobre hojas de cálculo navegando por aquí, como por ejemplo:
Y muchos más recursos que iré añadiendo para tu utilidad.